net-gunner/scripts/level.gd

class_name Level extends Node3D


const map_marker_templates : Dictionary[String, PackedScene] = {
	"pawn" :		preload("res://templates/markers/pawn_marker.tscn"),
	"friendly_trap":preload("res://templates/markers/friendly_trap_marker.tscn"),
	"enemy_trap":	preload("res://templates/markers/enemy_trap_marker.tscn"),
	"item":			preload("res://templates/markers/item_marker.tscn")
}


const pawn_controller = preload("res://templates/pawn_controller.tscn")
const trap_template = preload("res://templates/trap.tscn")
const camera_template = preload("res://templates/pawn_camera.tscn")

const camera_offset = Vector3(0, 10, 5.25)


@onready var floor_layer : GridMap = %Floor
@onready var ramp_layer : GridMap = %Ramps
@onready var marker_layer : GridMap = %Markers
@onready var pawns_node : Node3D = %Pawns
@onready var traps_node : Node3D = %Traps
@onready var cameras_node : Node3D = %Cameras
@onready var map_markers_node : Node3D = %MapMarkers
@export var difficulty : int = 1

var traps : Dictionary[Vector3i, Trap] = {}
var pawns : Dictionary[int, PawnController] = {}
var cameras : Dictionary[int, PawnCamera] = {}
var map_markers : Dictionary[Object, MapMarker] = {}

func _ready() -> void:
	Game.level = self
	if Game.mode == Game.Modes.STORY:
		setup()
		add_level_trap.call_deferred(Trap.Type.MINE, Vector3.ZERO, Vector3i(5,0,3))

func setup() -> void:
	if Multiplayer.is_host():
		spawn_players()

func spawn_players() -> void:
	for key in Game.pawns_selected:
		var pc : PawnController = pawn_controller.instantiate()
		var pd = Game.pawns_selected[key]
		pawns_node.add_child(pc,true)
		var traps : Array = []
		for trap : TrapSet in pd.starting_traps:
			var dict = {
				"type":trap.type,
				"qty":trap.qty
			}
			traps.append(dict)
		
		var position : Vector3
		if key == Multiplayer.id:
			position = Vector3(0,0,0)
		else:
			position = Vector3(3,0,0)
		
		pc.setup.rpc(key,traps,position)
		add_pawn_camera(pc)
		

func is_square_detected(crd) -> bool:
	return marker_layer.get_cell_item(crd + Vector3i(0,-1,0)) != GridMap.INVALID_CELL_ITEM

func detect_square(crd : Vector3i, mark : bool) -> bool:
	var cell = floor_layer.get_cell_item(crd)
	if cell == GridMap.INVALID_CELL_ITEM:
		return false
	
	marker_layer.set_cell_item(crd, 0 if mark else GridMap.INVALID_CELL_ITEM)
	if mark:
		var trap_crd = crd + Vector3i(0,1,0)
		if traps.has(trap_crd):
			var trap : Trap = traps[trap_crd]
			if trap.trap_owner != Multiplayer.id:
				trap.reveal()
	return true

@rpc("any_peer", "call_local", "reliable")
func add_pawn_camera(pawn : PawnController) -> void:
	if Multiplayer.is_host():
		var camera : PawnCamera = camera_template.instantiate()
		camera.position = pawn.global_position + camera_offset
		cameras_node.add_child(camera,true)
		camera.register_pawn.rpc(pawn.id)
		


func add_trap(trap : Trap, crd : Vector3i) -> void:
	trap.square = crd
	traps[crd] = trap
	trap.position = Vector3(crd) + Vector3(.5, 0, .5)
	add_child(trap, true)

func add_projectile(shot : Projectile) -> void:
	add_child(shot, true)
	
func remove_trap_square(crd : Vector3i) -> void:
	traps.erase(crd)

func get_square_trap(crd : Vector3i) -> Trap:
	if traps.has(crd):
		return traps[crd]
	else:
		return null



func is_valid_trap_square(crd : Vector3i) -> bool:
	if floor_layer.get_cell_item(crd + Vector3i(0,-1,0)) == GridMap.INVALID_CELL_ITEM:
		return false
	if traps.has(crd):
		return false
	return true

func add_vfx(vfx, crd : Vector3i) -> void:
	vfx.position = Vector3(crd) #+ Vector3(0.5, 0, 0.5)
	add_child(vfx, true)
	
func activate_trap(crd : Vector3i) -> void:
	if traps.has(crd):
		traps[crd].activate()
		

func generate_trap(type : Trap.Type, dir : Vector3, square : Vector3i):
	var trap = trap_template.instantiate()
	trap.setup(type, dir, -1)
	add_trap(trap, square)

func disarm_trap(crd : Vector3i) -> void:
	var trap = traps[crd]
	trap.disarm()
	traps.erase(crd)

func remove_map_marker(target) -> void:
	if !map_markers.has(target):
		printerr("Tried to remove a map marker for %s but marker does not exist!" % target.name)
	else:
		map_markers[target].queue_free()
		map_markers[target] = null

func add_map_marker(target) -> void:
	var marker : MapMarker
	var height : float
	if target is PawnController:
		marker = map_marker_templates.pawn.instantiate()
		height += 40
	elif target is Trap:
		if target.trap_owner == Multiplayer.id:
			marker = map_marker_templates.friendly_trap.instantiate()
		else:
			marker = map_marker_templates.enemy_trap.instantiate()
			marker.visible = false
			target.revealed.connect(marker._on_trap_revealed)
		height += 30
	elif target is Item:
		marker = map_marker_templates.item.instantiate()
		height += 10
	marker.register_target(target)
	map_markers[target] = marker
	map_markers_node.add_child(marker)
	marker.position += Vector3(0, height,0)

func add_level_trap(type : Trap.Type, facing : Vector3, crd : Vector3i) -> void:
	var trap = trap_template.instantiate()
	trap.setup(type, facing, -1)
	add_trap(trap, crd)